MobileGL/android-plugin/app/build.gradle

plugins {
    id 'com.android.application'
}

def mobileGlEnv = [
        LIBGL_ES             : '3',
        POJAV_RENDERER       : 'opengles3',
        MOBILEGL_BACKEND_TYPE: 'DirectVulkan',
]

def mobileGlEnvString = mobileGlEnv.collect { key, value -> "${key}=${value}" }.join(':')
def signingStoreFile = file('../keystore.jks')
def signingStorePassword = System.getenv('SIGNING_STORE_PASSWORD')
def signingKeyAlias = System.getenv('SIGNING_KEY_ALIAS')
def signingKeyPassword = System.getenv('SIGNING_KEY_PASSWORD')
def releaseSigningReady = signingStoreFile.exists()
        && signingStorePassword
        && signingKeyAlias
        && signingKeyPassword

android {
    namespace 'top.mobilegl.plugin'
    compileSdk 34
    ndkVersion '27.3.13750724'

    defaultConfig {
        applicationId 'top.mobilegl.plugin'
        minSdk 26
        targetSdk 34
        versionCode 1
        versionName 'dev'

        ndk {
            abiFilters 'arm64-v8a'
        }

        manifestPlaceholders = [
                des     : 'MobileGL',
                renderer: 'MobileGL:libMobileGL.so:/libMobileGL.so',
                boatEnv : mobileGlEnvString,
                pojavEnv: mobileGlEnvString,
        ]
    }

    if (releaseSigningReady) {
        signingConfigs {
            release {
                storeFile signingStoreFile
                storePassword signingStorePassword
                keyAlias signingKeyAlias
                keyPassword signingKeyPassword
            }
        }
    }

    buildTypes {
        release {
            minifyEnabled false
            if (releaseSigningReady) {
                signingConfig signingConfigs.release
            }
        }
    }

    packaging {
        jniLibs {
            useLegacyPackaging true
            excludes += ['**/libSPIRV-Tools-shared.so']
        }
    }
}

dependencies {
    implementation project(':MobileGL')
}